User Stories

As Mirko, I want to see all the sites that have been decommissioned so that I can write a report to the stakeholders.

Query

PREFIX tern-ssn: <https://w3id.org/tern/ontologies/ssn/>
PREFIX schema: <http://schema.org/>
PREFIX prov: <http://www.w3.org/ns/prov#>
select ?site_name ?time
where {
    ?id a tern-ssn:Site .
    ?id schema:name ?site_name .
	?id prov:invalidatedAtTime ?time .
} order by ?site_name

Result

	site_name	time
1	Karawatha Forest	"2018-01-01T00:00:00"^{^^xsd:date}

As Mirko, I want to see all the sites that are owned by James Cook University so that I can write a report to the stakeholders.

Query

PREFIX tern-ssn: <https://w3id.org/tern/ontologies/ssn/>
PREFIX schema: <http://schema.org/>
PREFIX tern-org: <https://w3id.org/tern/ontologies/org/>
select ?site_name
where {
    ?id a tern-ssn:Site .
    ?id schema:name ?site_name .
    
	# James Cook University
	<https://w3id.org/tern/resources/17226651-6f12-4ced-adef-16d09d001064> schema:owns ?OwnershipInfo .
    ?OwnershipInfo schema:typeOfGood ?id .
} order by ?site_name

Result

	site_name
1	Cow Bay
2	Daintree Rainforest

As Mirko, I want to see all the Affiliate SuperSites, its FluxNet ID, and date of commission, so that I can report to an external party.

Query

PREFIX tern-ssn: <https://w3id.org/tern/ontologies/ssn/>
PREFIX schema: <http://schema.org/>
PREFIX prov: <http://www.w3.org/ns/prov#>
select ?site_name ?fluxnet_identifier ?date_of_commission
where {
    ?id a tern-ssn:AffiliateSuperSite .
    ?id schema:name ?site_name .
    ?id tern-ssn:fluxnetID ?fluxnet_identifier .
    ?id prov:generatedAtTime ?date_of_commission
} order by ?site_name

Result

	site_name	fluxnet_identifier	date_of_commission
1	Samford Peri-urban	AU-Sam	"2010-06-01T00:00:00"^{^^xsd:date}

As Mirko, I want to see all the project managers of each site so that I can make a review of work responsibilities.

Query

PREFIX tern-ssn: <https://w3id.org/tern/ontologies/ssn/>
PREFIX tern-org: <https://w3id.org/tern/ontologies/org/>
PREFIX schema: <http://schema.org/>
select ?site_name ?project_manager
where {
    ?id a tern-ssn:Site .
    ?id schema:name ?site_name .
    ?id tern-org:projectManager+ ?project_manager_id .
    ?project_manager_id schema:name ?project_manager .
} order by ?site_name

Result

	site_name	project_manager
1	Alice Mulga	Derek Eamus
2	Boyagin Wandoo Woodland	Jason Beringer
3	Calperum Mallee	Wayne Meyer
4	Cumberland Plain	Matthias Boer
5	Daly River Uncleared	Lindsay Hutley
6	Dry River	Lindsay Hutley
7	Gingin Banksia Woodland	Matthias Boer
8	Great Western Woodlands	Suzanne Prober
9	Howard Springs	Lindsay Hutley
10	Karawatha Forest	Jean-Marc Hero
11	Litchfield Savanna	Lindsay Hutley
12	Mitchell Grass Rangeland	Peter Grace
13	Ridgefield	Jason Beringer
14	Robson Creek	Michael Liddell
15	Samford Peri-urban	Peter Grace
16	Sturt Plains	Lindsay Hutley
17	Ti Tree East	Derek Eamus
18	Tumbarumba Wet Eucalypt	Jacqui Stol
19	Warra Tall Eucalypt	Tim Wardlaw
20	Wombat String Bark Eucalypt	Stefan Arndt

As Mirko, I want to see all the sites and its classification so that I can review the nomenclature used for each site.

Query

PREFIX tern-ssn: <https://w3id.org/tern/ontologies/ssn/>
PREFIX schema: <http://schema.org/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sosa: <http://www.w3.org/ns/sosa/>
select ?site_name ?classification
where {
    ?id a tern-ssn:Site .
    ?id schema:name ?site_name .
    ?id a ?type .
    filter(!isBlank(?type))
    filter(?type != owl:Thing && ?type != schema:Thing && ?type != schema:Product && ?type != tern-ssn:Site && ?type != sosa:Platform && ?type != tern-ssn:FixedPlatform)
    ?type rdfs:label ?classification .
} order by ?site_name

Result

	site_name	classification
1	Alice Mulga	SuperSite
2	Boyagin Wandoo Woodland	SuperSite
3	Calperum Mallee	SuperSite
4	Cow Bay	Ecosystem processes site
5	Cumberland Plain	SuperSite
6	Daintree Rainforest	Ecosystem processes site
7	Daly River Uncleared	Ecosystem processes site
8	Dry River	Ecosystem processes site
9	Gingin Banksia Woodland	SuperSite
10	Great Western Woodlands	SuperSite
11	Howard Springs	Ecosystem processes site
12	Karawatha Forest	Ecosystem processes site
13	Litchfield Savanna	SuperSite
14	Mitchell Grass Rangeland	SuperSite
15	Ridgefield	Ecosystem processes site
16	Robson Creek	SuperSite
17	Samford Peri-urban	Affiliate super site
18	Sturt Plains	Ecosystem processes site
19	Ti Tree East	Ecosystem processes site
20	Tumbarumba Wet Eucalypt	SuperSite
21	Warra Tall Eucalypt	SuperSite
22	Whroo	Ecosystem processes site
23	Wombat String Bark Eucalypt	SuperSite

As Mirko, I want to see all the sites that are in the state of Queensland so that I can report to the Queensland Government.

Query

PREFIX tern-ssn: <https://w3id.org/tern/ontologies/ssn/>
PREFIX sosa: <http://www.w3.org/ns/sosa/>
PREFIX schema: <http://schema.org/>
select ?site_name
where {
    ?id a tern-ssn:Site .
    ?id schema:name ?site_name .
    ?id sosa:hasUltimateFeatureOfInterest <http://linked.data.gov.au/dataset/asgs2016/stateorterritory/3> .
} order by ?site_name

Result

	site_name
1	Cow Bay
2	Daintree Rainforest
3	Karawatha Forest
4	Mitchell Grass Rangeland
5	Samford Peri-urban

As Mirko, I want to see all the sites in the IBRA7 region Avon Wheatbelt so that I can report to the Australian Government.

Query

PREFIX tern-ssn: <https://w3id.org/tern/ontologies/ssn/>
PREFIX sosa: <http://www.w3.org/ns/sosa/>
PREFIX schema: <http://schema.org/>
select ?site_name
where {
    ?id a tern-ssn:Site .
    ?id schema:name ?site_name .
    ?id sosa:hasUltimateFeatureOfInterest <http://linked.data.gov.au/dataset/bioregion/AVW> .
} order by ?site_name

Result

	site_name
1	Boyagin Wandoo Woodland

As Mirko, I want to see all the sites in the WWF’s Eastern Australia Temperate Forests so I can collaborate with an international organisation.

Query

PREFIX tern-ssn: <https://w3id.org/tern/ontologies/ssn/>
PREFIX sosa: <http://www.w3.org/ns/sosa/>
PREFIX schema: <http://schema.org/>
select ?site_name
where {
    ?id a tern-ssn:Site .
    ?id schema:name ?site_name .
    ?id sosa:hasUltimateFeatureOfInterest <http://linked.data.gov.au/dataset/wwf-terr-ecoregions/14156> .
} order by ?site_name

Result

	site_name
1	Tumbarumba Wet Eucalypt
2	Whroo
3	Wombat String Bark Eucalypt

TERN Ecosystem Processes Sites User Stories

User Stories

As Mirko, I want to see all the sites that have been decommissioned so that I can write a report to the stakeholders.

Query

Result

As Mirko, I want to see all the sites that are owned by James Cook University so that I can write a report to the stakeholders.

Query

Result

As Mirko, I want to see all the Affiliate SuperSites, its FluxNet ID, and date of commission, so that I can report to an external party.

Query

Result

As Mirko, I want to see all the project managers of each site so that I can make a review of work responsibilities.

Query

Result

As Mirko, I want to see all the sites and its classification so that I can review the nomenclature used for each site.

Query

Result

As Mirko, I want to see all the sites that are in the state of Queensland so that I can report to the Queensland Government.

Query

Result

As Mirko, I want to see all the sites in the IBRA7 region Avon Wheatbelt so that I can report to the Australian Government.

Query

Result

As Mirko, I want to see all the sites in the WWF’s Eastern Australia Temperate Forests so I can collaborate with an international organisation.

Query

Result